NBDC RDF Portal

NBDC RDF Portalは、RDF形式の生命科学データベースを集積したポータルサイトです。RDF形式のデータは相互に参照したり連結することが容易であるため、多種多様な生命科学のデータベースを統合的に活用することが可能となります。本サイトでは、さまざまな研究機関から提供されたRDFデータセットをダウンロードしたり、SPARQL言語による検索を行うことができます。

The NBDC RDF Portal provides a collection of life science datasets in RDF (Resource Description Framework). The portal aims to accelerate integrative utilization of the heterogeneous datasets deposited by various research institutions and groups. In this portal, each dataset comes with a summary, downloadable files and a SPARQL endpoint.

Statistics

Update notes

Views

Datasets

List of RDF datasets with sorting and filtering optionsRDFデータセットのリスト

Statistics

Table of sortable statistics of RDF datasetsRDFデータセットの統計情報

Statistics

Graph of links between RDF datasetsRDFデータセット間の関係

Datasets

Detail

Detailed information of RDF datasets with download links and a SPARQL endpoint各RDFデータセットの詳細とダウンロード、SPARQL検索

Life science databases生命科学データベース

マニュアルManual

Submitting a RDF dataset

Currently, the NBDC RDF portal only accepts submissions from research groups in Japan due to the limitations of human and mechanical resources.

The requirements are RDF file(s), a metadata entry sheet, schema diagram(s) and sample SPARQL queries. Only openly available RDF dataset is accepted. In addition, it is necessary to correspond to NBDC's RDF review process. First of all, if you want to submit the RDF dataset, please contact rdf-portal @ integbio.jp.

Useful links

Datasets

Datasets view shows the list of the RDF datasets sorted by date last updated by default. Each database icon is linked to the corresponding detailed view. User can sort the datasets by alphabetical order, the number of triples or data provider in ascending or descending order by using the control panel in the bottom of the view. User can also filter the datasets by selecting the database categories.

Statistics

Statistics view shows the summary table of statistics of all datasets in this portal.

Links

Links view shows the networks consisting of the links among the RDF datasets in this portal and external datasets, which are listed in the Statistics section of each Details view.

SPARQL

SPARQL endpoint is available against all RDF datasets in this portal. User can execute a SPAQL query written in the query form by clicking the Run Query button. A number of prefixes for major ontologies such as dublin core, dcterms, skos, foaf, xsd, obo are predefined and user can user those prefixes without defining prefixes with @prefix notations. Predefined prefixes are listed in >https://integbio.jp/rdf/sparql?nsdecl< .

Details

Each dataset has its Details view. Details consists of five subsections: Specification, Linked datasets, Statistics, Schema, SPARQL examples and Stanzas.

Specification

Specification section shows meta-data of the dataset: the database categories, the provider, the creators, the latest version, the date issued and the license. The RDF files are also available in this section.

Linked datasets

Linked datasets section shows the statistics of the external links from the dataset. The links in th< form of '>an resource in the dataset< rdfs:seeAlso >an external URI registered in identifiers.org<' are enumerated

Statistics

Statistics section shows the detailed statistics such as the number of each class and property used.

Schema

Schema section shows the schematic image of the RDF model.

SPARQL examples

SPARQL examples section shows example SPARQL queries against the dataset. By clicking the SPARQL button below each query new browser window of the NBDC SPARQL endpoints service will be opened with the example query filled in the query from. User can directly execute the query by clicking the Run Query button below the query form.

Stanzas

Stanza is a web application querying SPRQL endpoints, which is developed by the TogoStanza framework. Stanzas section shows the stanzas using the RDF dataset.

SPARQL samples

Here are some SPARQL query samples against the NBDC RDF portal.

Sample 1

PREFIX up:<http://purl.uniprot.org/core/>
SELECT DISTINCT ?protein ?protein_name ?go ?go_label
{
   <http://purl.jp/bio/101/opentggates/Probe/1367452_at> rdfs:seeAlso ?protein .
   SERVICE <http://sparql.uniprot.org/sparql> {
     ?protein rdfs:label ?protein_name ;
       up:classifiedWith ?go .
     ?go a <http://www.w3.org/2002/07/owl#Class> ;
        rdfs:label ?go_label
   }
}

Sample 2

Counts the number of PubMed document citations in each dataset

PREFIX dcterms: <http://purl.org/dc/terms/> 
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#> 

SELECT ?graph COUNT(DISTINCT ?article) AS ?articles 
WHERE { 
　GRAPH ?graph {
    ?s dcterms:references ?article
    FILTER (REGEX(?article, "ncbi.nlm.nih.gov/pubmed"))
  }
} ORDER BY DESC(?articles)

Sample 3

Retrieve a sample exposed to doxorubicin and the blood test result

PREFIX tgo:     <http://purl.jp/bio/101/opentggates/ontology/>
PREFIX rdf:     <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs:    <http://www.w3.org/2000/01/rdf-schema#>
PREFIX xsd:     <http://www.w3.org/2001/XMLSchema#>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX obo:     <http://purl.obolibrary.org/obo/>
PREFIX sio:     <http://semanticscience.org/resource/>
PREFIX cmo:     <http://integbio.jp/rdf/ontology/cmo>

SELECT DISTINCT ?sample_id ?organ ?pathograde_label ?measurement_type ?v ?unit

WHERE {
  ?compound a tgo:ChemicalCompound ;
            rdfs:label "doxorubicin" .
  ?exp_condition tgo:exposedCompound ?compound .
  ?sample tgo:experimentalCondition ?exp_condition ;
          dcterms:identifier ?sample_id ;
          tgo:organ obo:UBERON_0002107 ;
          dcterms:isPartOf ?individual_animal .
  obo:UBERON_0002107 rdfs:label ?organ .

  ?pathology a tgo:Pathology ;
             tgo:hasSample ?sample ;
             tgo:grade ?pathograde .
  ?pathograde rdfs:label ?pathograde_label .
  FILTER(lang(?pathograde_label) = "en")

  ?individual_animal sio:SIO_000216 ?measurement_value .

  ?measurement_value a ?m ;
                     sio:SIO_000300 ?v .
  OPTIONAL {?m rdfs:label ?measurement_type}
  OPTIONAL {?measurement_value sio:SIO_000221 ?u .
            ?u rdfs:label ?unit }
  
}

Sample 4

Count peptide spectrum matches of a protein

PREFIX jpost: <http://rdf.jpostdb.org/ontology/jpost.owl#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX obo: <http://purl.obolibrary.org/obo/>
PREFIX up: <http://purl.uniprot.org/uniprot/>
SELECT DISTINCT ?sequence (COUNT (?psm) AS ?psm_count)
WHERE {
  VALUES ?uniprot { up:P01112 }
  ?protein jpost:hasDatabaseSequence ?uniprot ;
           jpost:hasPeptideEvidence/jpost:hasPeptide ?peptide .
  ?peptide jpost:hasSequence [ a obo:MS_1001344 ;
                             rdf:value ?sequence ] ;
           jpost:hasPsm ?psm .
}
ORDER BY DESC (?psm_count)

sample 5

Retrieve PDB entries having a secondary structure with beta-sheet to loop to beta-sheet and forming hairpin structure

PREFIX PDBo: <http://rdf.wwpdb.org/schema/pdbx-v40.owl#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>

SELECT ?pdb
       ?pdb_id
       ?title
       ?sheet
       ?sheet_range_1
       ?sheet_range_1_beg
       ?sheet_range_1_end
       ?sheet_range_2
       ?sheet_range_2_beg
       ?sheet_range_2_end
       ?dist1 ?dist2
FROM <http://rdf.integbio.jp/dataset/pdbj>
WHERE {
  ?pdb dcterms:identifier ?pdb_id .
  ?pdb dc:title ?title .
  ?pdb PDBo:has_struct_sheetCategory ?sheet_category .
  ?sheet_category a PDBo:struct_sheetCategory .
  ?sheet_category PDBo:has_struct_sheet ?sheet .
  ?sheet a PDBo:struct_sheet .
  ?sheet PDBo:struct_sheet.id ?sheet_id .
  ?sheet PDBo:referenced_by_struct_sheet_order ?sheet_order .
  ?sheet_order a PDBo:struct_sheet_order .
  ?sheet_order PDBo:struct_sheet_order.sense "anti-parallel" .
  ?sheet_order PDBo:struct_sheet_order.range_id_1 ?sheet_range_1_id .
  ?sheet_order PDBo:struct_sheet_order.range_id_2 ?sheet_range_2_id .
  ?sheet PDBo:referenced_by_struct_sheet_range ?sheet_range_1 .
  ?sheet_range_1 PDBo:struct_sheet_range.id ?sheet_range_1_id .
  ?sheet_range_1 PDBo:struct_sheet_range.beg_auth_seq_id ?sheet_range_1_beg .
  ?sheet_range_1 PDBo:struct_sheet_range.end_auth_seq_id ?sheet_range_1_end .
  ?sheet PDBo:referenced_by_struct_sheet_range ?sheet_range_2 .
  ?sheet_range_2 PDBo:struct_sheet_range.id ?sheet_range_2_id .
  ?sheet_range_2 PDBo:struct_sheet_range.beg_auth_seq_id ?sheet_range_2_beg .
  ?sheet_range_2 PDBo:struct_sheet_range.end_auth_seq_id ?sheet_range_2_end .
  BIND((xsd:integer(?sheet_range_2_beg) - xsd:integer(?sheet_range_1_end)) AS ?dist1)
  BIND((xsd:integer(?sheet_range_1_beg) - xsd:integer(?sheet_range_2_end)) AS ?dist2)
  FILTER((?dist1 < 6 && ?dist1 > 1) || (?dist2 < 6 && ?dist2 > 1))
} LIMIT 1000

Sample 6

Retrieve UniProt URIs, ligands, organisms and references from wwPDB/RDF

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX PDBo: <https://rdf.wwpdb.org/schema/pdbx-v50.owl#>
PREFIX dcterms: <http://purl.org/dc/terms/>

SELECT DISTINCT ?up ?compound ?taxon ?pubmed
FROM <http://rdf.integbio.jp/dataset/pdbj>
WHERE {
  ?pdb a PDBo:datablock .
  ?pdb dcterms:identifier ?pdb_id .
  ?pdb PDBo:has_entityCategory ?entity_category .
  ?entity_category PDBo:has_entity ?entity .
  ?entity PDBo:referenced_by_struct_ref ?struct_ref .
  ?struct_ref PDBo:link_to_uniprot ?up .
  ?entity PDBo:referenced_by_entity_src_gen ?entity_src_gen .
  ?entity_src_gen PDBo:entity_src_gen.pdbx_gene_src_ncbi_taxonomy_id ?ncbi_taxon .
  ?entity_src_gen rdfs:seeAlso ?taxon .
  FILTER(REGEX(?taxon, STR(?ncbi_taxon)))
  ?entity_nonpoly PDBo:of_datablock ?pdb .
  ?entity_nonpoly PDBo:pdbx_entity_nonpoly.comp_id ?comp_id .
  BIND(CONCAT("https://rdf.wwpdb.org/pdb/", ?pdb_id) AS ?comp_prefix)
  BIND(CONCAT(?comp_prefix, "/chem_comp/") AS ?comp_prefix_2)
  BIND(CONCAT(?comp_prefix_2, ?comp_id) AS ?compound)
  ?pdb PDBo:has_citationCategory ?citation_category .
  ?citation_category PDBo:has_citation ?citation .
  ?citation dcterms:references ?pubmed .
} LIMIT 100

Datasets

Datasets ページでは、RDFデータセットの一覧が、デフォルトでは更新日順に表示されます。それぞれのデータセットのアイコンは、各データセットのDetailsページにリンクされています。画面下部にある表示設定パネルで、更新日以外にも、アルファベット順、RDFトリプル数順、データ提供者順に、降順または昇順で並べ替えることができます。また、各データセットのデータベースカタログ分類を選ぶことで、表示されるデータセットを絞り込むこともできます。

Statistics

Statistics ページでは、本ポータルサイトに収録された全てのデータセットの統計情報を要約したテーブルが表示されます。

Links

Links ページでは、本ポータルに収録されたRDFデータセットおよび、外部のデータセットの間のリンクから構成されるネットーワーク図が表示されます。リンク情報は、各データセットのDetailsページのStatisticsに一覧されているものを利用しています。

SPARQL

全てのRDFデータセットに大して、SPARQLクエリを実行するためのエンドポイントを提供しています。Query: フォームに記述したSPARQLクエリを、Run Queryボタンをクリックすることで実行することができます。dublin core, dcterms, skos, foaf, xsd, obo 等の主要なオントロジーについては本ポータルにもロードされており、@prefix 記法で定義することなく、予め定義された接頭辞を利用することができます。利用できる接頭辞は、>https://integbio.jp/rdf/sparql?nsdecl< で参照できます。

Details

Details ページでは、各データセットの詳細情報が表示されます。Specification, Linked datasets, Statistics, SPARQL examples, Stanzas の5つのセクションから構成されています。

Specification

Specification セクションには、各データセットに関する、データベースカテゴリー、データ提供者、データ構築者、最新バージョン、構築日、ライセンス等のメタ情報が表示されます。RDFファイルそのものも、このセクションからダウンロードすることができます。

Linked datasets

Linked datasets セクションには、外部リンクへの数が表示されています。次の形式のトリプル '>本データセットのURI< rdfs:seeAlso >identifiers.orgのURI<' の数を利用しています。

Statistics

Statistics セクションには、各クラス、各プロパティ毎のトリプル数等の詳細な統計情報が表示されます。

Schema

Schema セクションには、各データセットのRDFモデルのスキーマ図が表示されます。

SPARQL examples

SPARQL examples セクションでは、各データセットに関するSPARQLクエリの例が表示されます。各SPARQLクエリの下にあるSPARQLボタンを押すことで、SPARQLエンドポイントサービスのページが新しいウインドウで表示されます。query フォームには、SPARQL exmaple が記述されいるので、Run Query ボタンを押すことで、直接クエリを実行することができます。

Stanzas

スタンザとは、TogoStanza を用いて作られたSPARQLを利用するウェブアプリケーションのことです。
Stanzas セクションでは、各RDFデータセットを利用した、スタンザアプリケーションが表示されています。